Generating PDF documents from Markdown

On the Neuron® you can generate PDF documents from Markdown via script. The way to do it, is as follows:

• Generate Markdown text for the content you want to include in the PDF document.
• Parse the Markdown using the ParseMarkdown function.
• From the parsed markdown, you can now generate LaTeX from the Markdown document object. You can download MikTeX as an implementation of TeX on most platforms.
• Save the generated LaTeX to a text file.
• Call pdflatex.exe using the ShellExecute script function. This will generate the PDF document from the LaTeX file.

If you want to make the PDF file downloadable, you need to save the PDF document in a folder under the Root folder under the gateway ProgramData folder.

The following script function will take any Markdown, and convert it to a PDF document. Before calling the ShellExecute function, it will check if a PDF document is already generated for the document, if so, the existing PDF document is used. Finally, the function converts the file name of the PDF document, to an URL that can be shared, and which others can use to download the PDF document. (For private PDF documents, you need to place the PDF document in another folder, not accessible via the web server of the gateway.)

CreateDownloadablePdf([Markdown]):=
(
	H:=Base64UrlEncode(Sha2_256(Utf8Encode(Markdown))).Insert(4,"\\").Insert(2,"\\");
	FileNameBase:=Waher.IoTGateway.Gateway.RootFolder+"PDF\\"+H;
	PdfFileName:=FileNameBase+".pdf";
	if !System.IO.File.Exists(PdfFileName) then
	(
		PdfFolder:=System.IO.Path.GetDirectoryName(FileNameBase);
		if !System.IO.Directory.Exists(PdfFolder) then
			System.IO.Directory.CreateDirectory(PdfFolder);
		Doc:=ParseMarkdown(Markdown);
		LaTeX:=Doc.GenerateLaTeX();
		SaveFile(LaTeX,FileNameBase+".tex");
		ShellExecute("C:\\Program Files\\MiKTeX\\miktex\\bin\\x64\\pdflatex.exe",
			"-enable-8bit-chars -enable-installer -enable-write18 -verbose \""+FileNameBase+".tex\"",
			PdfFolder);
	);
	Waher.IoTGateway.Gateway.GetUrl("/PDF/"+H.Replace("\\","/")+".pdf")
);

Note: The script assumes MikTeX is installed on the Neuron® for all users. If another TeX distribution is used, or if installing MikTeX for a particular user, the path needs to point to the correspondig installation.

Note 2: You will need a Neuron® with a buildtime of 2023-04-11 or later.

Note 3: TeX is built around pluggable packages. When installing TeX, make sure you either know what packages are needed, and install those, or allow for uninstalled packages to be downloaded and installed automatically on the server, when needed. Unless all referenced packages are available, PDF generation may be impaired. Also, PDF generation may be slow the first time a package is referenced, if it needs to be downloaded. One way to know what packages are needed, is to generate LaTeX, and manually convert it to PDF via one of the GUI tools provided by the TeX package. Such tools can be configured to prompt the user if new packages need to be installed.

To generate a PDF document, you call the function from script, as follows:

CreateDownloadablePdf("This *is* _a_ **test**.")

It will generate the following URL: https://lab.tagroot.io/PDF/s8/62/gokyHtmYYczQL2kjvUxOLCjjdN7KflSNHFEiLY4.pdf. You can download it here: PDF.

You can experiment with Markdown to LaTeX conversion in the Markdown Lab page, or similar page on your own Neuron®.

#documentation, #features, #api, #pdf